DBT-RISE-TGC/CMakeLists.txt

cmake_minimum_required(VERSION 3.12)

project(dbt-core-tgc VERSION 1.0.0)

include(GNUInstallDirs)

if(WITH_LLVM)
	if(DEFINED ENV{LLVM_HOME})
		find_path (LLVM_DIR LLVM-Config.cmake $ENV{LLVM_HOME}/lib/cmake/llvm)
	endif(DEFINED ENV{LLVM_HOME})
	find_package(LLVM REQUIRED CONFIG)
	message(STATUS "Found LLVM ${LLVM_PACKAGE_VERSION}")
	message(STATUS "Using LLVMConfig.cmake in: ${LLVM_DIR}")
	llvm_map_components_to_libnames(llvm_libs support core mcjit x86codegen x86asmparser)
endif()

#Mac needed variables (adapt for your needs - http://www.cmake.org/Wiki/CMake_RPATH_handling#Mac_OS_X_and_the_RPATH)
#set(CMAKE_MACOSX_RPATH ON)
#set(CMAKE_SKIP_BUILD_RPATH FALSE)
#set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
#set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib")
#set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)

add_subdirectory(softfloat)

# library files
FILE(GLOB TGC_SOURCES
    ${CMAKE_CURRENT_SOURCE_DIR}/src/iss/*.cpp 
    ${CMAKE_CURRENT_SOURCE_DIR}/src/vm/interp/vm_*.cpp
)
set(LIB_SOURCES 
	src/vm/fp_functions.cpp
    src/plugin/instruction_count.cpp
    src/plugin/cycle_estimate.cpp
    ${TGC_SOURCES}
)

if(WITH_LLVM)
  set(LIB_SOURCES ${LIB_SOURCES}
	src/vm/llvm/fp_impl.cpp
    #src/vm/llvm/vm_tgf_b.cpp
    #src/vm/llvm/vm_tgf_c.cpp
  )
endif()

# Define the library
add_library(${PROJECT_NAME} SHARED ${LIB_SOURCES})
# list code gen dependencies
if(TARGET ${CORE_NAME}_cpp)
    add_dependencies(${PROJECT_NAME} ${CORE_NAME}_cpp)
endif()

target_compile_options(${PROJECT_NAME} PRIVATE -Wno-shift-count-overflow)
target_include_directories(${PROJECT_NAME} PUBLIC incl)
target_link_libraries(${PROJECT_NAME} PUBLIC softfloat scc-util jsoncpp)
target_link_libraries(${PROJECT_NAME} PUBLIC -Wl,--whole-archive dbt-core -Wl,--no-whole-archive)
if(TARGET CONAN_PKG::elfio)
	target_link_libraries(${PROJECT_NAME} PUBLIC CONAN_PKG::elfio)
elseif(TARGET elfio::elfio)
    target_link_libraries(${PROJECT_NAME} PUBLIC elfio::elfio)
else()
	message(FATAL_ERROR "No elfio library found, maybe a find_package() call is missing")
endif()
#target_link_libraries(${PROJECT_NAME} PUBLIC ${Boost_program_options_LIBRARY} ${Boost_system_LIBRARY} ${Boost_thread_LIBRARY} ${Boost_filesystem_LIBRARY} )
set_target_properties(${PROJECT_NAME} PROPERTIES
  VERSION ${PROJECT_VERSION}
  FRAMEWORK FALSE
  PUBLIC_HEADER "${LIB_HEADERS}" # specify the public headers
)

include(FindSystemCPackage)
if(SystemC_FOUND)
	add_library(${PROJECT_NAME}_sc src/sysc/core_complex.cpp)
	target_compile_definitions(${PROJECT_NAME}_sc PUBLIC WITH_SYSTEMC)
    target_compile_definitions(${PROJECT_NAME} PRIVATE CORE_${CORE_NAME})
    if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/incl/iss/arch/tgc_b.h)
        target_compile_definitions(${PROJECT_NAME}_sc PRIVATE CORE_TGC_B)
    endif()
	if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/incl/iss/arch/tgc_c.h)
        target_compile_definitions(${PROJECT_NAME}_sc PRIVATE CORE_TGC_C)
    endif()
    if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/incl/iss/arch/tgc_d.h)
        target_compile_definitions(${PROJECT_NAME}_sc PRIVATE CORE_TGC_D)
    endif()
	target_link_libraries(${PROJECT_NAME}_sc PUBLIC ${PROJECT_NAME} scc)
	if(WITH_LLVM)
		target_link_libraries(${PROJECT_NAME}_sc PUBLIC ${llvm_libs})
	endif()
	set_target_properties(${PROJECT_NAME}_sc PROPERTIES
	  VERSION ${PROJECT_VERSION}
	  FRAMEWORK FALSE
	  PUBLIC_HEADER "${LIB_HEADERS}" # specify the public headers
	)
endif()

project(tgc-sim)
find_package(Boost COMPONENTS program_options system thread filesystem REQUIRED)

add_executable(${PROJECT_NAME} src/main.cpp)
# This sets the include directory for the reference project. This is the -I flag in gcc.
target_compile_definitions(${PROJECT_NAME} PRIVATE CORE_${CORE_NAME})
if(WITH_LLVM)
	target_compile_definitions(${PROJECT_NAME} PRIVATE WITH_LLVM)
	target_link_libraries(${PROJECT_NAME} PUBLIC ${llvm_libs})
endif()
# Links the target exe against the libraries
target_link_libraries(${PROJECT_NAME} dbt-core-tgc)
target_link_libraries(${PROJECT_NAME} jsoncpp)
if(TARGET Boost::program_options)
	target_link_libraries(${PROJECT_NAME} Boost::program_options Boost::thread)
else()
	target_link_libraries(${PROJECT_NAME} ${BOOST_program_options_LIBRARY} ${BOOST_thread_LIBRARY})
endif()
#target_link_libraries(${PROJECT_NAME} ${Boost_LIBRARIES}) #${Boost_program_options_LIBRARY} ${Boost_system_LIBRARY} ${Boost_filesystem_LIBRARY} ${Boost_thread_LIBRARY} )
target_link_libraries(${PROJECT_NAME} ${CMAKE_DL_LIBS})
if (Tcmalloc_FOUND)
    target_link_libraries(${PROJECT_NAME} ${Tcmalloc_LIBRARIES})
endif(Tcmalloc_FOUND)

install(TARGETS dbt-core-tgc tgc-sim
  EXPORT ${PROJECT_NAME}Targets            # for downstream dependencies
  ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR} COMPONENT libs   # static lib
  RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT libs   # binaries
  LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR} COMPONENT libs   # shared lib
  FRAMEWORK DESTINATION ${CMAKE_INSTALL_LIBDIR} COMPONENT libs # for mac
  PUBLIC_HEADER DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/${PROJECT_NAME} COMPONENT devel   # headers for mac (note the different component -> different package)
  INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}             # headers
)