262 lines
11 KiB
CMake
262 lines
11 KiB
CMake
cmake_minimum_required(VERSION 3.21)
|
|
|
|
set(BUILD_SHARED_LIBS OFF)
|
|
get_filename_component(THREADX4TGFS_ROOT "${CMAKE_CURRENT_LIST_DIR}/../.." ABSOLUTE)
|
|
|
|
if(NOT DEFINED CMAKE_TOOLCHAIN_FILE)
|
|
set(CMAKE_TOOLCHAIN_FILE
|
|
${THREADX4TGFS_ROOT}/cmake/rv32imac_gnu.cmake
|
|
CACHE FILEPATH "Toolchain file")
|
|
endif()
|
|
include(${CMAKE_TOOLCHAIN_FILE})
|
|
|
|
project(threadx_regression LANGUAGES C ASM)
|
|
enable_testing()
|
|
|
|
set(TARGET_MEM "ram_dram" CACHE STRING "memory map to use")
|
|
set(CMAKE_EXECUTABLE_SUFFIX_C ".elf")
|
|
|
|
set(THREADX_TEST_SIMULATOR
|
|
""
|
|
CACHE FILEPATH "Path to the RISC-V VP executable used by CTest")
|
|
if(NOT THREADX_TEST_SIMULATOR)
|
|
message(FATAL_ERROR
|
|
"THREADX_TEST_SIMULATOR is not set. Configure with -DTHREADX_TEST_SIMULATOR=/path/to/riscv-vp")
|
|
endif()
|
|
|
|
if(CMAKE_SYSTEM_PROCESSOR STREQUAL "risc-v32")
|
|
set(THREADX_TEST_ISA "rv32imac_m")
|
|
elseif(CMAKE_SYSTEM_PROCESSOR STREQUAL "risc-v64")
|
|
set(THREADX_TEST_ISA "rv64imac_m")
|
|
else()
|
|
message(FATAL_ERROR
|
|
"Unsupported CMAKE_SYSTEM_PROCESSOR for VP ISA selection: ${CMAKE_SYSTEM_PROCESSOR}")
|
|
endif()
|
|
|
|
set(__THREAD_LOCAL_STORAGE OFF)
|
|
add_subdirectory(${THREADX4TGFS_ROOT}/third-party/picolibc ${CMAKE_BINARY_DIR}/picolibc)
|
|
target_link_libraries(c PUBLIC gcc)
|
|
|
|
set(THREADX_CUSTOM_PORT ${THREADX4TGFS_ROOT}/port/threadx)
|
|
add_subdirectory(${THREADX4TGFS_ROOT}/third-party/threadx ${CMAKE_BINARY_DIR}/threadx)
|
|
target_link_libraries(threadx PUBLIC c)
|
|
target_compile_definitions(threadx PUBLIC TX_REGRESSION_TEST)
|
|
|
|
set(MOONLIGHT_TRAP_SOURCE_INPUT ${THREADX4TGFS_ROOT}/port/moonlight/src/trap_non_vectored.c)
|
|
set(MOONLIGHT_TRAP_SOURCE ${CMAKE_BINARY_DIR}/generated/trap_non_vectored.c)
|
|
add_custom_command(
|
|
OUTPUT ${MOONLIGHT_TRAP_SOURCE}
|
|
COMMAND bash ${CMAKE_CURRENT_LIST_DIR}/generate_trap_file.sh
|
|
${MOONLIGHT_TRAP_SOURCE_INPUT}
|
|
${MOONLIGHT_TRAP_SOURCE}
|
|
DEPENDS ${MOONLIGHT_TRAP_SOURCE_INPUT}
|
|
${CMAKE_CURRENT_LIST_DIR}/generate_trap_file.sh
|
|
VERBATIM
|
|
)
|
|
add_custom_target(threadx_regression_generated_trap DEPENDS ${MOONLIGHT_TRAP_SOURCE})
|
|
set_source_files_properties(${MOONLIGHT_TRAP_SOURCE} PROPERTIES GENERATED TRUE)
|
|
|
|
add_subdirectory(${THREADX4TGFS_ROOT}/port/moonlight ${CMAKE_BINARY_DIR}/port/moonlight)
|
|
add_dependencies(moonlight_platform_common threadx_regression_generated_trap)
|
|
|
|
function(setup_target TARGET)
|
|
set(options)
|
|
set(oneValueArgs PLATFORM_TARGET)
|
|
set(multiValueArgs LIBRARIES SOURCES)
|
|
cmake_parse_arguments(ST "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
|
|
if(ST_UNPARSED_ARGUMENTS)
|
|
message(FATAL_ERROR "setup_target(${TARGET} ...): unknown args: ${ST_UNPARSED_ARGUMENTS}")
|
|
endif()
|
|
|
|
add_executable(${TARGET})
|
|
set_target_properties(${TARGET} PROPERTIES
|
|
RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}
|
|
)
|
|
if(ST_PLATFORM_TARGET)
|
|
target_add_moonlight_platform(${TARGET} PLATFORM_TARGET ${ST_PLATFORM_TARGET})
|
|
else()
|
|
target_add_moonlight_platform(${TARGET})
|
|
endif()
|
|
|
|
if(ST_SOURCES)
|
|
target_sources(${TARGET} PRIVATE ${ST_SOURCES})
|
|
endif()
|
|
|
|
if(ST_LIBRARIES)
|
|
target_link_libraries(${TARGET} PRIVATE ${ST_LIBRARIES})
|
|
endif()
|
|
|
|
target_link_options(${TARGET} PRIVATE
|
|
-nostartfiles
|
|
-nostdlib
|
|
-T ${THREADX4TGFS_ROOT}/src/${TARGET_MEM}.lds
|
|
-Wl,--gc-sections
|
|
-Wl,-Map=${CMAKE_BINARY_DIR}/${TARGET}.map)
|
|
|
|
add_custom_command(TARGET ${TARGET} POST_BUILD
|
|
COMMAND ${OBJCOPY} -O ihex $<TARGET_FILE:${TARGET}> ${CMAKE_BINARY_DIR}/${TARGET}.hex
|
|
COMMAND ${OBJCOPY} -O binary $<TARGET_FILE:${TARGET}> ${CMAKE_BINARY_DIR}/${TARGET}.bin
|
|
COMMAND ${OBJDUMP} -S $<TARGET_FILE:${TARGET}> > ${CMAKE_BINARY_DIR}/${TARGET}.dis
|
|
)
|
|
endfunction()
|
|
|
|
set(TX_REGRESSION_DIR
|
|
${THREADX4TGFS_ROOT}/third-party/threadx/test/tx/regression
|
|
)
|
|
set(TX_CMAKE_DIR
|
|
${THREADX4TGFS_ROOT}/third-party/threadx/test/tx/cmake
|
|
)
|
|
|
|
set(TX_REGRESSION_CASES
|
|
${TX_REGRESSION_DIR}/threadx_block_memory_basic_test.c
|
|
${TX_REGRESSION_DIR}/threadx_block_memory_error_detection_test.c
|
|
${TX_REGRESSION_DIR}/threadx_block_memory_information_test.c
|
|
${TX_REGRESSION_DIR}/threadx_block_memory_prioritize_test.c
|
|
${TX_REGRESSION_DIR}/threadx_block_memory_suspension_test.c
|
|
${TX_REGRESSION_DIR}/threadx_block_memory_suspension_timeout_test.c
|
|
${TX_REGRESSION_DIR}/threadx_block_memory_thread_terminate_test.c
|
|
${TX_REGRESSION_DIR}/threadx_byte_memory_basic_test.c
|
|
${TX_REGRESSION_DIR}/threadx_byte_memory_information_test.c
|
|
${TX_REGRESSION_DIR}/threadx_byte_memory_prioritize_test.c
|
|
${TX_REGRESSION_DIR}/threadx_byte_memory_suspension_test.c
|
|
${TX_REGRESSION_DIR}/threadx_byte_memory_suspension_timeout_test.c
|
|
${TX_REGRESSION_DIR}/threadx_byte_memory_thread_contention_test.c
|
|
${TX_REGRESSION_DIR}/threadx_byte_memory_thread_terminate_test.c
|
|
${TX_REGRESSION_DIR}/threadx_event_flag_basic_test.c
|
|
${TX_REGRESSION_DIR}/threadx_event_flag_information_test.c
|
|
${TX_REGRESSION_DIR}/threadx_event_flag_isr_set_clear_test.c
|
|
${TX_REGRESSION_DIR}/threadx_event_flag_isr_wait_abort_test.c
|
|
${TX_REGRESSION_DIR}/threadx_event_flag_single_thread_terminate_test.c
|
|
${TX_REGRESSION_DIR}/threadx_event_flag_suspension_consume_test.c
|
|
${TX_REGRESSION_DIR}/threadx_event_flag_suspension_different_bits_consume_test.c
|
|
${TX_REGRESSION_DIR}/threadx_event_flag_suspension_different_bits_test.c
|
|
${TX_REGRESSION_DIR}/threadx_event_flag_suspension_test.c
|
|
${TX_REGRESSION_DIR}/threadx_event_flag_suspension_timeout_test.c
|
|
${TX_REGRESSION_DIR}/threadx_event_flag_thread_terminate_test.c
|
|
${TX_REGRESSION_DIR}/threadx_interrupt_control_test.c
|
|
${TX_REGRESSION_DIR}/threadx_mutex_basic_test.c
|
|
${TX_REGRESSION_DIR}/threadx_mutex_delete_test.c
|
|
${TX_REGRESSION_DIR}/threadx_mutex_information_test.c
|
|
${TX_REGRESSION_DIR}/threadx_mutex_nested_priority_inheritance_test.c
|
|
${TX_REGRESSION_DIR}/threadx_mutex_no_preemption_test.c
|
|
${TX_REGRESSION_DIR}/threadx_mutex_preemption_test.c
|
|
${TX_REGRESSION_DIR}/threadx_mutex_priority_inheritance_test.c
|
|
${TX_REGRESSION_DIR}/threadx_mutex_proritize_test.c
|
|
${TX_REGRESSION_DIR}/threadx_mutex_suspension_timeout_test.c
|
|
${TX_REGRESSION_DIR}/threadx_mutex_thread_terminate_test.c
|
|
${TX_REGRESSION_DIR}/threadx_queue_basic_eight_word_test.c
|
|
${TX_REGRESSION_DIR}/threadx_queue_basic_four_word_test.c
|
|
${TX_REGRESSION_DIR}/threadx_queue_basic_one_word_test.c
|
|
${TX_REGRESSION_DIR}/threadx_queue_basic_sixteen_word_test.c
|
|
${TX_REGRESSION_DIR}/threadx_queue_basic_two_word_test.c
|
|
${TX_REGRESSION_DIR}/threadx_queue_basic_max_message_size_test.c
|
|
${TX_REGRESSION_DIR}/threadx_queue_empty_suspension_test.c
|
|
${TX_REGRESSION_DIR}/threadx_queue_flush_no_suspension_test.c
|
|
${TX_REGRESSION_DIR}/threadx_queue_flush_test.c
|
|
${TX_REGRESSION_DIR}/threadx_queue_front_send_test.c
|
|
${TX_REGRESSION_DIR}/threadx_queue_full_suspension_test.c
|
|
${TX_REGRESSION_DIR}/threadx_queue_information_test.c
|
|
${TX_REGRESSION_DIR}/threadx_queue_prioritize.c
|
|
${TX_REGRESSION_DIR}/threadx_queue_suspension_timeout_test.c
|
|
${TX_REGRESSION_DIR}/threadx_queue_thread_terminate_test.c
|
|
${TX_REGRESSION_DIR}/threadx_semaphore_basic_test.c
|
|
${TX_REGRESSION_DIR}/threadx_semaphore_ceiling_put_test.c
|
|
${TX_REGRESSION_DIR}/threadx_semaphore_delete_test.c
|
|
${TX_REGRESSION_DIR}/threadx_semaphore_information_test.c
|
|
${TX_REGRESSION_DIR}/threadx_semaphore_non_preemption_test.c
|
|
${TX_REGRESSION_DIR}/threadx_semaphore_preemption_test.c
|
|
${TX_REGRESSION_DIR}/threadx_semaphore_prioritize.c
|
|
${TX_REGRESSION_DIR}/threadx_semaphore_thread_terminate_test.c
|
|
${TX_REGRESSION_DIR}/threadx_semaphore_timeout_test.c
|
|
${TX_REGRESSION_DIR}/threadx_thread_basic_execution_test.c
|
|
${TX_REGRESSION_DIR}/threadx_thread_basic_time_slice_test.c
|
|
${TX_REGRESSION_DIR}/threadx_thread_completed_test.c
|
|
${TX_REGRESSION_DIR}/threadx_thread_create_preemption_threshold_test.c
|
|
${TX_REGRESSION_DIR}/threadx_thread_delayed_suspension_test.c
|
|
${TX_REGRESSION_DIR}/threadx_thread_information_test.c
|
|
${TX_REGRESSION_DIR}/threadx_thread_multi_level_preemption_threshold_test.c
|
|
${TX_REGRESSION_DIR}/threadx_thread_multiple_non_current_test.c
|
|
${TX_REGRESSION_DIR}/threadx_thread_multiple_sleep_test.c
|
|
${TX_REGRESSION_DIR}/threadx_thread_multiple_suspension_test.c
|
|
${TX_REGRESSION_DIR}/threadx_thread_multiple_time_slice_test.c
|
|
${TX_REGRESSION_DIR}/threadx_thread_preemptable_suspension_test.c
|
|
${TX_REGRESSION_DIR}/threadx_thread_preemption_change_test.c
|
|
${TX_REGRESSION_DIR}/threadx_thread_priority_change.c
|
|
${TX_REGRESSION_DIR}/threadx_thread_relinquish_test.c
|
|
${TX_REGRESSION_DIR}/threadx_thread_reset_test.c
|
|
${TX_REGRESSION_DIR}/threadx_thread_simple_sleep_non_clear_test.c
|
|
${TX_REGRESSION_DIR}/threadx_thread_simple_sleep_test.c
|
|
${TX_REGRESSION_DIR}/threadx_thread_simple_suspend_test.c
|
|
${TX_REGRESSION_DIR}/threadx_thread_sleep_for_100ticks_test.c
|
|
${TX_REGRESSION_DIR}/threadx_thread_sleep_terminate_test.c
|
|
${TX_REGRESSION_DIR}/threadx_thread_stack_checking_test.c
|
|
${TX_REGRESSION_DIR}/threadx_thread_terminate_delete_test.c
|
|
${TX_REGRESSION_DIR}/threadx_thread_time_slice_change_test.c
|
|
${TX_REGRESSION_DIR}/threadx_thread_wait_abort_and_isr_test.c
|
|
${TX_REGRESSION_DIR}/threadx_thread_wait_abort_test.c
|
|
${TX_REGRESSION_DIR}/threadx_time_get_set_test.c
|
|
${TX_REGRESSION_DIR}/threadx_timer_activate_deactivate_test.c
|
|
${TX_REGRESSION_DIR}/threadx_timer_deactivate_accuracy_test.c
|
|
${TX_REGRESSION_DIR}/threadx_timer_information_test.c
|
|
${TX_REGRESSION_DIR}/threadx_timer_large_timer_accuracy_test.c
|
|
${TX_REGRESSION_DIR}/threadx_timer_multiple_accuracy_test.c
|
|
${TX_REGRESSION_DIR}/threadx_timer_multiple_test.c
|
|
${TX_REGRESSION_DIR}/threadx_timer_simple_test.c
|
|
${TX_REGRESSION_DIR}/threadx_trace_basic_test.c
|
|
${TX_REGRESSION_DIR}/threadx_initialize_kernel_setup_test.c
|
|
)
|
|
|
|
set(TX_REGRESSION_TARGETS)
|
|
|
|
add_library(
|
|
threadx_regression_support STATIC
|
|
${TX_REGRESSION_DIR}/testcontrol.c
|
|
${TX_CMAKE_DIR}/samples/fake.c
|
|
)
|
|
target_link_libraries(threadx_regression_support PUBLIC threadx c)
|
|
target_compile_definitions(
|
|
threadx_regression_support
|
|
PUBLIC
|
|
TX_REGRESSION_TEST
|
|
CTEST
|
|
BATCH_TEST
|
|
TEST_STACK_SIZE_PRINTF=4096
|
|
)
|
|
|
|
function(add_threadx_regression_test TEST_SOURCE)
|
|
get_filename_component(TEST_NAME ${TEST_SOURCE} NAME_WE)
|
|
|
|
if(TEST_NAME STREQUAL "threadx_initialize_kernel_setup_test")
|
|
set(test_libraries threadx)
|
|
else()
|
|
set(test_libraries threadx_regression_support)
|
|
endif()
|
|
|
|
setup_target(
|
|
${TEST_NAME}
|
|
LIBRARIES ${test_libraries}
|
|
SOURCES ${TEST_SOURCE}
|
|
)
|
|
|
|
list(APPEND TX_REGRESSION_TARGETS ${TEST_NAME})
|
|
set(TX_REGRESSION_TARGETS ${TX_REGRESSION_TARGETS} PARENT_SCOPE)
|
|
|
|
add_test(
|
|
NAME ${TEST_NAME}
|
|
COMMAND ${THREADX_TEST_SIMULATOR}
|
|
--isa=${THREADX_TEST_ISA}
|
|
-f $<TARGET_FILE:${TEST_NAME}>
|
|
-m 60s
|
|
)
|
|
set_tests_properties(${TEST_NAME} PROPERTIES TIMEOUT 60)
|
|
endfunction()
|
|
|
|
foreach(test_case ${TX_REGRESSION_CASES})
|
|
add_threadx_regression_test(${test_case})
|
|
endforeach()
|
|
|
|
add_custom_target(
|
|
threadx_regression_build
|
|
DEPENDS ${TX_REGRESSION_TARGETS}
|
|
)
|