adds toplevel CMakeLists.txt for tests

test/CMakeLists.txt

@@ -1,3 +1,67 @@
 cmake_minimum_required(VERSION 3.21)
 
-add_subdirectory(threadx)
+set(BUILD_SHARED_LIBS OFF)
+get_filename_component(THREADX4TGFS_ROOT "${CMAKE_CURRENT_LIST_DIR}/.." ABSOLUTE)
+
+if(NOT DEFINED CMAKE_TOOLCHAIN_FILE)
+  set(CMAKE_TOOLCHAIN_FILE
+      ${THREADX4TGFS_ROOT}/cmake/rv32imac_gnu.cmake
+      CACHE FILEPATH "Toolchain file")
+endif()
+include(${CMAKE_TOOLCHAIN_FILE})
+
+set(__THREAD_LOCAL_STORAGE OFF)
+add_subdirectory(${THREADX4TGFS_ROOT}/third-party/picolibc ${CMAKE_BINARY_DIR}/picolibc)
+target_link_libraries(c PUBLIC gcc)
+
+set(THREADX_CUSTOM_PORT ${THREADX4TGFS_ROOT}/port/threadx)
+add_subdirectory(${THREADX4TGFS_ROOT}/third-party/threadx ${CMAKE_BINARY_DIR}/threadx)
+target_link_libraries(threadx PUBLIC c)
+target_compile_definitions(threadx PUBLIC TX_REGRESSION_TEST)
+
+project(threadx_regression C ASM)
+enable_testing()
+set(TARGET_MEM "ram_dram" CACHE STRING "memory map to use")
+set(CMAKE_EXECUTABLE_SUFFIX_C ".elf")
+
+add_subdirectory(${THREADX4TGFS_ROOT}/port/moonlight ${CMAKE_BINARY_DIR}/port/moonlight)
+
+function(setup_target TARGET)
+  set(options)
+  set(multiValueArgs LIBRARIES SOURCES)
+  cmake_parse_arguments(ST "${options}" "" "${multiValueArgs}" ${ARGN})
+  if(ST_UNPARSED_ARGUMENTS)
+    message(FATAL_ERROR "setup_target(${TARGET} ...): unknown args: ${ST_UNPARSED_ARGUMENTS}")
+  endif()
+
+  add_executable(${TARGET})
+  set_target_properties(${TARGET} PROPERTIES
+    RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}
+  )
+  target_add_moonlight_platform(${TARGET})
+
+  if(ST_SOURCES)
+    target_sources(${TARGET} PRIVATE ${ST_SOURCES})
+  endif()
+
+  if(ST_LIBRARIES)
+    target_link_libraries(${TARGET} PRIVATE ${ST_LIBRARIES})
+  endif()
+
+  target_link_options(${TARGET} PRIVATE
+    -nostartfiles
+    -nostdlib
+    -T ${THREADX4TGFS_ROOT}/src/${TARGET_MEM}.lds
+    -Wl,--gc-sections
+    -Wl,-Map=${CMAKE_BINARY_DIR}/${TARGET}.map)
+
+  add_custom_command(TARGET ${TARGET} POST_BUILD
+    COMMAND ${OBJCOPY} -O ihex $<TARGET_FILE:${TARGET}> ${CMAKE_BINARY_DIR}/${TARGET}.hex
+    COMMAND ${OBJCOPY} -O binary $<TARGET_FILE:${TARGET}> ${CMAKE_BINARY_DIR}/${TARGET}.bin
+    COMMAND ${SIZE} $<TARGET_FILE:${TARGET}>
+    COMMAND ${OBJDUMP} -S $<TARGET_FILE:${TARGET}> > ${CMAKE_BINARY_DIR}/${TARGET}.dis
+    COMMENT "Creating collateral for ${TARGET}"
+  )
+endfunction()
+
+add_subdirectory(threadx regression_targets)