initial commit

2026-01-27 20:45:47 +01:00
commit 1e5eb44ca9
53 changed files with 11048 additions and 0 deletions
--- a/src/sections.ld
+++ b/src/sections.ld
@@ -0,0 +1,184 @@
+PHDRS
+{
+  flash PT_LOAD;
+  ram_init PT_LOAD;
+  tls PT_TLS;
+  ram PT_NULL;
+  dram PT_NULL;
+}
+
+SECTIONS
+{
+  __stack_size = DEFINED(__stack_size) ? __stack_size : 2K;
+  __stack_segment_size = DEFINED(__stack_segment_size) ? __stack_segment_size : __stack_size;
+  .init ORIGIN(REGION_TEXT)        :
+  {
+    KEEP (*(.text.init.enter))
+    KEEP (*(.text.init.*))
+    KEEP (*(.text.init))
+    KEEP (*(SORT_NONE(.init)))
+    KEEP (*(.text.libgloss.start))
+  } >REGION_TEXT AT>REGION_TEXT :flash
+
+  .text           :
+  {
+    *(.text.unlikely .text.unlikely.*)
+    *(.text.startup .text.startup.*)
+    *(.text .text.*)
+    *(.gnu.linkonce.t.*)
+  } >REGION_TEXT AT>REGION_TEXT :flash
+
+  .fini           :
+  {
+    KEEP (*(SORT_NONE(.fini)))
+  } >REGION_TEXT AT>REGION_TEXT :flash
+
+  PROVIDE (__etext = .);
+  PROVIDE (_etext = .);
+  PROVIDE (etext = .);
+
+  .rodata         :
+  {
+    *(.rdata)
+    *(.rodata .rodata.*)
+    *(.gnu.linkonce.r.*)
+  } >REGION_RODATA AT>REGION_RODATA :flash
+
+  .srodata        :
+  {
+    *(.srodata.cst16)
+    *(.srodata.cst8)
+    *(.srodata.cst4)
+    *(.srodata.cst2)
+    *(.srodata .srodata.*)
+  } >REGION_RODATA AT>REGION_RODATA :flash
+
+  . = ALIGN(4);
+
+  .preinit_array  :
+  {
+    PROVIDE_HIDDEN (__preinit_array_start = .);
+    KEEP (*(.preinit_array))
+    PROVIDE_HIDDEN (__preinit_array_end = .);
+  } >REGION_RODATA AT>REGION_RODATA :flash
+
+  .init_array     :
+  {
+    PROVIDE_HIDDEN (__init_array_start = .);
+    KEEP (*(SORT_BY_INIT_PRIORITY(.init_array.*) SORT_BY_INIT_PRIORITY(.ctors.*)))
+    KEEP (*(.init_array EXCLUDE_FILE (*crtbegin.o *crtbegin?.o *crtend.o *crtend?.o ) .ctors))
+    PROVIDE_HIDDEN (__init_array_end = .);
+  } >REGION_RODATA AT>REGION_RODATA :flash
+
+  .fini_array     :
+  {
+    PROVIDE_HIDDEN (__fini_array_start = .);
+    KEEP (*(SORT_BY_INIT_PRIORITY(.fini_array.*) SORT_BY_INIT_PRIORITY(.dtors.*)))
+    KEEP (*(.fini_array EXCLUDE_FILE (*crtbegin.o *crtbegin?.o *crtend.o *crtend?.o ) .dtors))
+    PROVIDE_HIDDEN (__fini_array_end = .);
+  } >REGION_RODATA AT>REGION_RODATA :flash
+
+  .ctors          :
+  {
+    /* gcc uses crtbegin.o to find the start of
+       the constructors, so we make sure it is
+       first.  Because this is a wildcard, it
+       doesn't matter if the user does not
+       actually link against crtbegin.o; the
+       linker won't look for a file to match a
+       wildcard.  The wildcard also means that it
+       doesn't matter which directory crtbegin.o
+       is in.  */
+    KEEP (*crtbegin.o(.ctors))
+    KEEP (*crtbegin?.o(.ctors))
+    /* We don't want to include the .ctor section from
+       the crtend.o file until after the sorted ctors.
+       The .ctor section from the crtend file contains the
+       end of ctors marker and it must be last */
+    KEEP (*(EXCLUDE_FILE (*crtend.o *crtend?.o ) .ctors))
+    KEEP (*(SORT(.ctors.*)))
+    KEEP (*(.ctors))
+  } >REGION_RODATA AT>REGION_RODATA :flash
+
+  .dtors          :
+  {
+    KEEP (*crtbegin.o(.dtors))
+    KEEP (*crtbegin?.o(.dtors))
+    KEEP (*(EXCLUDE_FILE (*crtend.o *crtend?.o ) .dtors))
+    KEEP (*(SORT(.dtors.*)))
+    KEEP (*(.dtors))
+  } >REGION_RODATA AT>REGION_RODATA :flash
+
+  .lalign         :
+  {
+    . = ALIGN(4);
+    PROVIDE( _data_lma = . );
+  } >REGION_RODATA AT>REGION_RODATA :flash
+
+  .data          : ALIGN(4)
+  {
+    __DATA_BEGIN__ = .;
+    *(.data .data.*)
+    *(.gnu.linkonce.d.*)
+    __SDATA_BEGIN__ = .;
+    *(.sdata .sdata.*)
+    *(.gnu.linkonce.s.*)
+  } >REGION_DATA AT>REGION_RODATA :ram_init
+
+  .tdata : ALIGN(8) {
+    PROVIDE( __tls_base = . );
+	  *(.tdata .tdata.* .gnu.linkonce.td.*)
+  } >REGION_DATA AT>REGION_RODATA :tls :ram_init
+  
+  PROVIDE( __data_source = LOADADDR(.data) );
+  PROVIDE( __data_start = ADDR(.data)  );
+  PROVIDE( __data_end =  ADDR(.tdata) + SIZEOF(.tdata) );
+  
+  PROVIDE( __tdata_source = LOADADDR(.tdata) );
+  PROVIDE( __tdata_size = SIZEOF(.tdata) );
+
+  .tbss : ALIGN(8) {
+	  *(.tbss .tbss.* .gnu.linkonce.tb.*)
+	  *(.tcommon .tcommon.*)
+	  PROVIDE( __tls_end = . );
+  } >REGION_DATA AT>REGION_DATA :tls :ram
+
+  PROVIDE( __tbss_size = SIZEOF(.tbss) );
+  PROVIDE( __tls_size = __tls_end - __tls_base );
+
+  .tbss_space : ALIGN(8) {
+	  . = . + __tbss_size;
+  } >REGION_DATA :ram
+
+  .bss            :
+  {
+    __BSS_BEGIN__ = .;
+    *(.sbss*)
+    *(.gnu.linkonce.sb.*)
+    *(.bss .bss.*)
+    *(.gnu.linkonce.b.*)
+    *(COMMON)
+    . = ALIGN(4);
+    __BSS_END__ = .;
+
+  } >REGION_BSS AT>REGION_BSS :ram
+
+  PROVIDE( __bss_start = ADDR(.tbss) );
+  PROVIDE( __bss_end = ADDR(.bss) + SIZEOF(.bss) );
+
+  __global_pointer$ = MIN(__SDATA_BEGIN__ + 0x800,  MAX(__DATA_BEGIN__ + 0x800, __BSS_END__ - 0x800));
+  PROVIDE( _end = . );
+  PROVIDE( end = . );
+
+  .stack ORIGIN(ram) + LENGTH(ram) - __stack_segment_size :
+  {
+    PROVIDE( _heap_end = . );
+    . = __stack_segment_size;
+    PROVIDE( _sp = . );
+  } >REGION_BSS AT>REGION_BSS :ram
+
+
+  
+  PROVIDE( tohost = . );
+  PROVIDE( fromhost = . + 8 );
+}