Initial checkin

2017-09-17 15:06:10 +02:00
commit 48d7daf9d9
17 changed files with 1041 additions and 0 deletions
--- a/cmake/Common.cmake
+++ b/cmake/Common.cmake
@ -0,0 +1,20 @@
+# Function to link between sub-projects
+function(add_dependent_subproject subproject_name)
+    #if (NOT TARGET ${subproject_name}) # target unknown
+    if(NOT PROJECT_${subproject_name}) # var unknown because we build only this subproject
+        find_package(${subproject_name} CONFIG REQUIRED)
+    else () # we know the target thus we are doing a build from the top directory
+        include_directories(../${subproject_name}/incl)
+    endif ()
+endfunction(add_dependent_subproject)
+
+# Make sure we tell the topdir CMakeLists that we exist (if build from topdir)
+get_directory_property(hasParent PARENT_DIRECTORY)
+if(hasParent)
+    set(PROJECT_${PROJECT_NAME} true PARENT_SCOPE)
+endif()
+
+# Function to link between sub-projects
+function(add_dependent_header subproject_name)
+    include_directories(../${subproject_name}/incl)
+endfunction(add_dependent_header)
--- a/cmake/DoxygenTarget.cmake
+++ b/cmake/DoxygenTarget.cmake
@ -0,0 +1,24 @@
+function(PrepareDocTarget)
+
+  # Configure the doxygen config file with current settings:
+  configure_file(documentation-config.doxygen.in ${CMAKE_CURRENT_BINARY_DIR}/documentation-config.doxygen @ONLY)
+
+  # Set the name of the target : "doc" if it doesn't already exist and "doc<projectname>" if it does.
+  # This way we make sure to have a single "doc" target. Either it is the one of the top directory or
+  # it is the one of the subproject that we are compiling alone.
+  set(DOC_TARGET_NAME "doc")
+  if(TARGET doc)
+    set(DOC_TARGET_NAME "doc${PROJECT_NAME}")
+  endif()
+
+  add_custom_target(${DOC_TARGET_NAME} ${TARGET_ALL}
+      ${DOXYGEN_EXECUTABLE} ${CMAKE_CURRENT_BINARY_DIR}/documentation-config.doxygen
+      WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
+      COMMENT "Generating API documentation using doxygen for ${PROJECT_NAME}" VERBATIM)
+
+  set(INSTALL_DOC_DIR ${CMAKE_BINARY_DIR}/doc/${PROJECT_NAME}/html)
+  file(MAKE_DIRECTORY ${INSTALL_DOC_DIR}) # needed for install
+
+  install(DIRECTORY ${INSTALL_DOC_DIR} DESTINATION share/${PROJECT_NAME}-${VERSION_MAJOR} COMPONENT doc)
+
+endfunction()
--- a/cmake/FindSystemC.cmake
+++ b/cmake/FindSystemC.cmake
@ -0,0 +1,91 @@
+SET(_SYSTEMC_HINTS
+  "[HKEY_LOCAL_MACHINE\\SOFTWARE\\SystemC\\2.2;SystemcHome]/include"
+  ${SYSTEMC_PREFIX}/include
+  ${SYSTEMC_PREFIX}/lib
+  ${SYSTEMC_PREFIX}/lib-linux
+  ${SYSTEMC_PREFIX}/lib-linux64
+  ${SYSTEMC_PREFIX}/lib-macos
+  $ENV{SYSTEMC_PREFIX}/include
+  $ENV{SYSTEMC_PREFIX}/lib
+  $ENV{SYSTEMC_PREFIX}/lib-linux
+  $ENV{SYSTEMC_PREFIX}/lib-linux64
+  $ENV{SYSTEMC_PREFIX}/lib-macos
+  $ENV{SYSTEMC_HOME}/include
+  $ENV{SYSTEMC_HOME}/lib
+  $ENV{SYSTEMC_HOME}/lib-linux
+  $ENV{SYSTEMC_HOME}/lib-linux64
+  $ENV{SYSTEMC_HOME}/lib-macos
+  ${CMAKE_INSTALL_PREFIX}/include
+  ${CMAKE_INSTALL_PREFIX}/lib
+  ${CMAKE_INSTALL_PREFIX}/lib-linux
+  ${CMAKE_INSTALL_PREFIX}/lib-linux64
+  ${CMAKE_INSTALL_PREFIX}/lib-macos
+  )
+SET(_SYSTEMC_PATHS
+  /usr/include/systemc
+  /usr/lib
+  /usr/lib-linux
+  /usr/lib-linux64
+  /usr/lib-macos
+  /usr/local/include/sysc
+  /usr/local/lib
+  /usr/local/lib-linux
+  /usr/local/lib-linux64
+  /usr/local/lib-macos
+  )
+FIND_FILE(_SYSTEMC_HEADER_FILE
+  NAMES systemc
+  HINTS ${_SYSTEMC_HINTS}
+  PATHS ${_SYSTEMC_PATHS}
+  PATH_SUFFIXES sysc/kernel
+)
+
+FIND_FILE(_SCV_HEADER_FILE
+  NAMES scv.h
+  HINTS ${_SYSTEMC_HINTS}
+  PATHS ${_SYSTEMC_PATHS}
+  PATH_SUFFIXES sysc/kernel
+)
+
+if(NOT _SYSTEMC_HEADER_FILE STREQUAL _SYSTEMC_HEADER_FILE-NOTFOUND)
+  set(SystemC_FOUND TRUE)
+endif(NOT _SYSTEMC_HEADER_FILE STREQUAL _SYSTEMC_HEADER_FILE-NOTFOUND)
+
+if(NOT _SCV_HEADER_FILE STREQUAL _SCV_HEADER_FILE-NOTFOUND)
+  set(SCV_FOUND TRUE)
+endif(NOT _SCV_HEADER_FILE STREQUAL _SCV_HEADER_FILE-NOTFOUND)
+
+FIND_PATH(SystemC_INCLUDE_DIRS
+  NAMES systemc.h
+  HINTS ${_SYSTEMC_HINTS}
+  PATHS ${_SYSTEMC_PATHS}
+)
+
+FIND_PATH(SystemC_LIBRARY_DIR
+  NAMES libsystemc.a
+  HINTS ${_SYSTEMC_HINTS}
+  PATHS ${_SYSTEMC_PATHS}
+)
+
+FIND_PATH(SCV_INCLUDE_DIRS
+  NAMES scv.h
+  HINTS ${_SYSTEMC_HINTS}
+  PATHS ${_SYSTEMC_PATHS}
+)
+
+FIND_PATH(SCV_LIBRARY_DIRS
+  NAMES libscv.a
+  HINTS ${_SYSTEMC_HINTS}
+  PATHS ${_SYSTEMC_PATHS}
+)
+
+if(SystemC_FOUND)
+        set(SystemC_LIBRARIES systemc)
+        message(STATUS "SystemC header files are taken from ${SystemC_INCLUDE_DIRS}")
+        message(STATUS "SystemC library is taken from ${SystemC_LIBRARY_DIR}")
+        if(SCV_FOUND)
+            set(SCV_LIBRARIES scv)
+            message(STATUS "SCV header files are taken from ${SCV_INCLUDE_DIRS}")
+            message(STATUS "SCV library is taken from ${SCV_LIBRARY_DIRS}")
+        endif(SCV_FOUND)
+endif(SystemC_FOUND)
--- a/cmake/GetGitRevisionDescription.cmake
+++ b/cmake/GetGitRevisionDescription.cmake
@ -0,0 +1,130 @@
+# - Returns a version string from Git
+#
+# These functions force a re-configure on each git commit so that you can
+# trust the values of the variables in your build system.
+#
+#  get_git_head_revision(<refspecvar> <hashvar> [<additional arguments to git describe> ...])
+#
+# Returns the refspec and sha hash of the current head revision
+#
+#  git_describe(<var> [<additional arguments to git describe> ...])
+#
+# Returns the results of git describe on the source tree, and adjusting
+# the output so that it tests false if an error occurs.
+#
+#  git_get_exact_tag(<var> [<additional arguments to git describe> ...])
+#
+# Returns the results of git describe --exact-match on the source tree,
+# and adjusting the output so that it tests false if there was no exact
+# matching tag.
+#
+# Requires CMake 2.6 or newer (uses the 'function' command)
+#
+# Original Author:
+# 2009-2010 Ryan Pavlik <rpavlik@iastate.edu> <abiryan@ryand.net>
+# http://academic.cleardefinition.com
+# Iowa State University HCI Graduate Program/VRAC
+#
+# Copyright Iowa State University 2009-2010.
+# Distributed under the Boost Software License, Version 1.0.
+# (See accompanying file LICENSE_1_0.txt or copy at
+# http://www.boost.org/LICENSE_1_0.txt)
+
+if(__get_git_revision_description)
+	return()
+endif()
+set(__get_git_revision_description YES)
+
+# We must run the following at "include" time, not at function call time,
+# to find the path to this module rather than the path to a calling list file
+get_filename_component(_gitdescmoddir ${CMAKE_CURRENT_LIST_FILE} PATH)
+
+function(get_git_head_revision _refspecvar _hashvar)
+	set(GIT_PARENT_DIR "${CMAKE_CURRENT_LIST_DIR}")
+	set(GIT_DIR "${GIT_PARENT_DIR}/.git")
+	while(NOT EXISTS "${GIT_DIR}")	# .git dir not found, search parent directories
+		set(GIT_PREVIOUS_PARENT "${GIT_PARENT_DIR}")
+		get_filename_component(GIT_PARENT_DIR ${GIT_PARENT_DIR} PATH)
+		if(GIT_PARENT_DIR STREQUAL GIT_PREVIOUS_PARENT)
+			# We have reached the root directory, we are not in git
+			set(${_refspecvar} "GITDIR-NOTFOUND" PARENT_SCOPE)
+			set(${_hashvar} "GITDIR-NOTFOUND" PARENT_SCOPE)
+			return()
+		endif()
+		set(GIT_DIR "${GIT_PARENT_DIR}/.git")
+	endwhile()
+	# check if this is a submodule
+	if(NOT IS_DIRECTORY ${GIT_DIR})
+		file(READ ${GIT_DIR} submodule)
+		string(REGEX REPLACE "gitdir: (.*)\n$" "\\1" GIT_DIR_RELATIVE ${submodule})
+		get_filename_component(SUBMODULE_DIR ${GIT_DIR} PATH)
+		get_filename_component(GIT_DIR ${SUBMODULE_DIR}/${GIT_DIR_RELATIVE} ABSOLUTE)
+	endif()
+	set(GIT_DATA "${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/git-data")
+	if(NOT EXISTS "${GIT_DATA}")
+		file(MAKE_DIRECTORY "${GIT_DATA}")
+	endif()
+
+	if(NOT EXISTS "${GIT_DIR}/HEAD")
+		return()
+	endif()
+	set(HEAD_FILE "${GIT_DATA}/HEAD")
+	configure_file("${GIT_DIR}/HEAD" "${HEAD_FILE}" COPYONLY)
+
+	configure_file("${_gitdescmoddir}/GetGitRevisionDescription.cmake.in"
+		"${GIT_DATA}/grabRef.cmake"
+		@ONLY)
+	include("${GIT_DATA}/grabRef.cmake")
+
+	set(${_refspecvar} "${HEAD_REF}" PARENT_SCOPE)
+	set(${_hashvar} "${HEAD_HASH}" PARENT_SCOPE)
+endfunction()
+
+function(git_describe _var)
+	if(NOT GIT_FOUND)
+		find_package(Git QUIET)
+	endif()
+	get_git_head_revision(refspec hash)
+	if(NOT GIT_FOUND)
+		set(${_var} "GIT-NOTFOUND" PARENT_SCOPE)
+		return()
+	endif()
+	if(NOT hash)
+		set(${_var} "HEAD-HASH-NOTFOUND" PARENT_SCOPE)
+		return()
+	endif()
+
+	# TODO sanitize
+	#if((${ARGN}" MATCHES "&&") OR
+	#	(ARGN MATCHES "||") OR
+	#	(ARGN MATCHES "\\;"))
+	#	message("Please report the following error to the project!")
+	#	message(FATAL_ERROR "Looks like someone's doing something nefarious with git_describe! Passed arguments ${ARGN}")
+	#endif()
+
+	#message(STATUS "Arguments to execute_process: ${ARGN}")
+
+	execute_process(COMMAND
+		"${GIT_EXECUTABLE}"
+		describe
+		${hash}
+		${ARGN}
+		WORKING_DIRECTORY
+		"${CMAKE_SOURCE_DIR}"
+		RESULT_VARIABLE
+		res
+		OUTPUT_VARIABLE
+		out
+		ERROR_QUIET
+		OUTPUT_STRIP_TRAILING_WHITESPACE)
+	if(NOT res EQUAL 0)
+		set(out "${out}-${res}-NOTFOUND")
+	endif()
+
+	set(${_var} "${out}" PARENT_SCOPE)
+endfunction()
+
+function(git_get_exact_tag _var)
+	git_describe(out --exact-match ${ARGN})
+	set(${_var} "${out}" PARENT_SCOPE)
+endfunction()
--- a/cmake/GetGitRevisionDescription.cmake.in
+++ b/cmake/GetGitRevisionDescription.cmake.in
@ -0,0 +1,41 @@
+#
+# Internal file for GetGitRevisionDescription.cmake
+#
+# Requires CMake 2.6 or newer (uses the 'function' command)
+#
+# Original Author:
+# 2009-2010 Ryan Pavlik <rpavlik@iastate.edu> <abiryan@ryand.net>
+# http://academic.cleardefinition.com
+# Iowa State University HCI Graduate Program/VRAC
+#
+# Copyright Iowa State University 2009-2010.
+# Distributed under the Boost Software License, Version 1.0.
+# (See accompanying file LICENSE_1_0.txt or copy at
+# http://www.boost.org/LICENSE_1_0.txt)
+
+set(HEAD_HASH)
+
+file(READ "@HEAD_FILE@" HEAD_CONTENTS LIMIT 1024)
+
+string(STRIP "${HEAD_CONTENTS}" HEAD_CONTENTS)
+if(HEAD_CONTENTS MATCHES "ref")
+	# named branch
+	string(REPLACE "ref: " "" HEAD_REF "${HEAD_CONTENTS}")
+	if(EXISTS "@GIT_DIR@/${HEAD_REF}")
+		configure_file("@GIT_DIR@/${HEAD_REF}" "@GIT_DATA@/head-ref" COPYONLY)
+	else()
+		configure_file("@GIT_DIR@/packed-refs" "@GIT_DATA@/packed-refs" COPYONLY)
+		file(READ "@GIT_DATA@/packed-refs" PACKED_REFS)
+		if(${PACKED_REFS} MATCHES "([0-9a-z]*) ${HEAD_REF}")
+			set(HEAD_HASH "${CMAKE_MATCH_1}")
+		endif()
+	endif()
+else()
+	# detached HEAD
+	configure_file("@GIT_DIR@/HEAD" "@GIT_DATA@/head-ref" COPYONLY)
+endif()
+
+if(NOT HEAD_HASH)
+	file(READ "@GIT_DATA@/head-ref" HEAD_HASH LIMIT 1024)
+	string(STRIP "${HEAD_HASH}" HEAD_HASH)
+endif()
--- a/cmake/PackageConfigurator.cmake
+++ b/cmake/PackageConfigurator.cmake
@ -0,0 +1,44 @@
+# Create package-config files :
+#  - <projectname>ConfigVersion.cmake
+#  - <projectname>Config.cmake
+# They are installed in lib/cmake/<projectname>.
+#
+# Required variables :
+#  - VERSION
+#  - PROJECT_NAME
+#
+
+# Include needed for 'write_basic_package_version_file'
+include(CMakePackageConfigHelpers)
+
+write_basic_package_version_file(
+  "${CMAKE_CURRENT_BINARY_DIR}/cmake/${PROJECT_NAME}ConfigVersion.cmake"
+  VERSION ${VERSION}
+  COMPATIBILITY AnyNewerVersion
+)
+
+configure_file(cmake/${PROJECT_NAME}Config.cmake
+  "${CMAKE_CURRENT_BINARY_DIR}/cmake/${PROJECT_NAME}Config.cmake"
+  COPYONLY
+)
+
+# Destination
+set(config_install_dir lib/cmake/${PROJECT_NAME})
+
+# Config installation
+#   * <prefix>/lib/cmake/<project>/<project>Targets.cmake
+install(
+  EXPORT ${PROJECT_NAME}Targets
+  DESTINATION ${config_install_dir}
+)
+
+# Config installation
+#   * <prefix>/lib/cmake/<project>/<project>Config.cmake
+#   * <prefix>/lib/cmake/<project>/<project>ConfigVersion.cmake
+install(
+  FILES
+    cmake/${PROJECT_NAME}Config.cmake
+    "${CMAKE_CURRENT_BINARY_DIR}/cmake/${PROJECT_NAME}ConfigVersion.cmake"
+  DESTINATION ${config_install_dir}
+  COMPONENT devel
+)
--- a/cmake/Submodules.cmake
+++ b/cmake/Submodules.cmake
@ -0,0 +1,53 @@
+if(EXISTS "${PROJECT_SOURCE_DIR}/.gitmodules")
+message(STATUS "Updating submodules to their latest/fixed versions")
+message(STATUS "(this can take a while, please be patient)")
+
+### First, get all submodules in
+if(${GIT_SUBMODULES_CHECKOUT_QUIET})
+    execute_process(
+        COMMAND             git submodule update --init --recursive
+        WORKING_DIRECTORY   ${PROJECT_SOURCE_DIR}
+        OUTPUT_QUIET
+        ERROR_QUIET
+    )
+else()
+    execute_process(
+        COMMAND             git submodule update --init --recursive
+        WORKING_DIRECTORY   ${PROJECT_SOURCE_DIR}
+    )
+endif()
+
+### Then, checkout each submodule to the specified commit
+# Note: Execute separate processes here, to make sure each one is run,
+# should one crash (because of branch not existing, this, that ... whatever)
+foreach(GIT_SUBMODULE ${GIT_SUBMODULES})
+
+    if( "${GIT_SUBMODULE_VERSION_${GIT_SUBMODULE}}" STREQUAL "" )
+        message(STATUS "no specific version given for submodule ${GIT_SUBMODULE}, checking out master")
+        set(GIT_SUBMODULE_VERSION_${GIT_SUBMODULE} "master")
+    endif()
+
+    if( "${GIT_SUBMODULE_DIR_${GIT_SUBMODULE}}" STREQUAL "" )
+        set(GIT_SUBMODULES_DIRECTORY external)
+    else()
+        set(GIT_SUBMODULES_DIRECTORY ${GIT_SUBMODULE_DIR_${GIT_SUBMODULE}})
+    endif()
+
+    if(${GIT_SUBMODULES_CHECKOUT_QUIET})
+        execute_process(
+            COMMAND             git checkout ${GIT_SUBMODULE_VERSION_${GIT_SUBMODULE}}
+            WORKING_DIRECTORY   ${PROJECT_SOURCE_DIR}/${GIT_SUBMODULES_DIRECTORY}/${GIT_SUBMODULE}
+            OUTPUT_QUIET
+            ERROR_QUIET
+        )
+    else()
+        message(STATUS "checking out ${GIT_SUBMODULE}'s commit/tag ${GIT_SUBMODULE_VERSION_${GIT_SUBMODULE}}")
+        execute_process(
+            COMMAND             git checkout ${GIT_SUBMODULE_VERSION_${GIT_SUBMODULE}}
+            WORKING_DIRECTORY   ${PROJECT_SOURCE_DIR}/${GIT_SUBMODULES_DIRECTORY}/${GIT_SUBMODULE}
+        )
+    endif()
+
+endforeach(${GIT_SUBMODULE})
+
+endif()