forked from Mirrors/opensbi
fefa548803
Split the RO/RX and RW sections so that they can have independent pmp entries with required permissions. The split size is ensured to be a power-of-2 as required by pmp. _fw_rw_offset symbol marks the beginning of the data section. Signed-off-by: Himanshu Chauhan <hchauhan@ventanamicro.com> Reviewed-by: Anup Patel <anup@brainfault.org>
101 lines
1.8 KiB
Plaintext
101 lines
1.8 KiB
Plaintext
/*
|
|
* SPDX-License-Identifier: BSD-2-Clause
|
|
*
|
|
* Copyright (c) 2019 Western Digital Corporation or its affiliates.
|
|
*
|
|
* Authors:
|
|
* Anup Patel <anup.patel@wdc.com>
|
|
*/
|
|
|
|
. = FW_TEXT_START;
|
|
/* Don't add any section between FW_TEXT_START and _fw_start */
|
|
PROVIDE(_fw_start = .);
|
|
|
|
. = ALIGN(0x1000); /* Need this to create proper sections */
|
|
|
|
/* Beginning of the code section */
|
|
|
|
.text :
|
|
{
|
|
PROVIDE(_text_start = .);
|
|
*(.entry)
|
|
*(.text)
|
|
. = ALIGN(8);
|
|
PROVIDE(_text_end = .);
|
|
}
|
|
|
|
/* End of the code sections */
|
|
|
|
. = ALIGN(0x1000); /* Ensure next section is page aligned */
|
|
|
|
/* Beginning of the read-only data sections */
|
|
|
|
.rodata :
|
|
{
|
|
PROVIDE(_rodata_start = .);
|
|
*(.rodata .rodata.*)
|
|
. = ALIGN(8);
|
|
PROVIDE(_rodata_end = .);
|
|
}
|
|
|
|
/* End of the read-only data sections */
|
|
|
|
. = ALIGN(0x1000); /* Ensure next section is page aligned */
|
|
|
|
/*
|
|
* PMP regions must be to be power-of-2. RO/RW will have separate
|
|
* regions, so ensure that the split is power-of-2.
|
|
*/
|
|
. = ALIGN(1 << LOG2CEIL(SIZEOF(.rodata) + SIZEOF(.text)));
|
|
|
|
PROVIDE(_fw_rw_offset = (. - _fw_start));
|
|
|
|
/* Beginning of the read-write data sections */
|
|
|
|
.data :
|
|
{
|
|
PROVIDE(_data_start = .);
|
|
|
|
*(.sdata)
|
|
*(.sdata.*)
|
|
*(.data)
|
|
*(.data.*)
|
|
*(.readmostly.data)
|
|
*(*.data)
|
|
. = ALIGN(8);
|
|
|
|
PROVIDE(_data_end = .);
|
|
}
|
|
|
|
.dynsym : {
|
|
PROVIDE(__dyn_sym_start = .);
|
|
*(.dynsym)
|
|
PROVIDE(__dyn_sym_end = .);
|
|
}
|
|
|
|
.rela.dyn : {
|
|
PROVIDE(__rel_dyn_start = .);
|
|
*(.rela*)
|
|
. = ALIGN(8);
|
|
PROVIDE(__rel_dyn_end = .);
|
|
}
|
|
|
|
. = ALIGN(0x1000); /* Ensure next section is page aligned */
|
|
|
|
.bss :
|
|
{
|
|
PROVIDE(_bss_start = .);
|
|
*(.sbss)
|
|
*(.sbss.*)
|
|
*(.bss)
|
|
*(.bss.*)
|
|
. = ALIGN(8);
|
|
PROVIDE(_bss_end = .);
|
|
}
|
|
|
|
/* End of the read-write data sections */
|
|
|
|
. = ALIGN(0x1000); /* Need this to create proper sections */
|
|
|
|
PROVIDE(_fw_end = .);
|