cmake_minimum_required(VERSION 3.24)
project(smp_demo LANGUAGES C ASM)

set(THREADX_COMMON_SMP_DIR ${CMAKE_CURRENT_SOURCE_DIR}/../../third-party/threadx/common_smp)
if(NOT EXISTS "${THREADX_COMMON_SMP_DIR}")
    message(FATAL_ERROR "could not find ThreadX SMP sources, is the submodule checked out?")
endif()

set(THREADX_SMP_CUSTOM_INC
    ${CMAKE_CURRENT_SOURCE_DIR}/inc
    ${CMAKE_CURRENT_SOURCE_DIR}/../moonlight
)
set(THREADX_SMP_CUSTOM_SRC
    src/tx_initialize_low_level.S
    src/tx_thread_context_restore.S
    src/tx_thread_context_save.S
    src/tx_thread_schedule.S
    src/tx_thread_smp_core_get.S
    src/tx_thread_smp_core_preempt.c
    src/tx_thread_smp_current_state_get.S
    src/tx_thread_smp_current_thread_get.S
    src/tx_thread_smp_initialize_wait.S
    src/tx_thread_smp_low_level_initialize.S
    src/tx_thread_smp_protect.S
    src/tx_thread_smp_time_get.c
    src/tx_thread_smp_unprotect.S
    src/tx_thread_stack_build.S
    src/tx_thread_system_return.S
)
set(THREADX_SMP_GENERATED_INC_DIR ${CMAKE_CURRENT_BINARY_DIR}/generated)
set(THREADX_SMP_OFFSET_SOURCE ${CMAKE_CURRENT_SOURCE_DIR}/src/tx_asm_offsets.c)
set(THREADX_SMP_OFFSET_ASM ${THREADX_SMP_GENERATED_INC_DIR}/tx_asm_offsets.s)
set(THREADX_SMP_OFFSET_INC ${THREADX_SMP_GENERATED_INC_DIR}/tx_asm_offsets.inc)
set(THREADX_SMP_OFFSET_INCLUDE_DIRS
    ${THREADX_COMMON_SMP_DIR}/inc
    ${THREADX_SMP_CUSTOM_INC}
)
set(THREADX_SMP_OFFSET_COMPILE_DEFINITIONS
    TX_QUEUE_MESSAGE_MAX_SIZE=16
)
set(THREADX_SMP_OFFSET_INCLUDE_ARGS ${THREADX_SMP_OFFSET_INCLUDE_DIRS})
list(TRANSFORM THREADX_SMP_OFFSET_INCLUDE_ARGS PREPEND -I)
set(THREADX_SMP_OFFSET_DEFINE_ARGS ${THREADX_SMP_OFFSET_COMPILE_DEFINITIONS})
list(TRANSFORM THREADX_SMP_OFFSET_DEFINE_ARGS PREPEND -D)
set(THREADX_SMP_OFFSET_CFLAGS ${CMAKE_C_FLAGS})
if(CMAKE_BUILD_TYPE)
    string(TOUPPER ${CMAKE_BUILD_TYPE} THREADX_SMP_BUILD_TYPE_UPPER)
    list(APPEND THREADX_SMP_OFFSET_CFLAGS ${CMAKE_C_FLAGS_${THREADX_SMP_BUILD_TYPE_UPPER}})
endif()
separate_arguments(THREADX_SMP_OFFSET_CFLAGS)

file(GLOB THREADX_SMP_SOURCES ${THREADX_COMMON_SMP_DIR}/src/*.c)
add_library(threadx_smp STATIC)
target_sources(threadx_smp PRIVATE
    ${THREADX_SMP_SOURCES}
    ${THREADX_SMP_CUSTOM_SRC}
)
target_include_directories(threadx_smp PUBLIC
    ${THREADX_COMMON_SMP_DIR}/inc
    ${THREADX_SMP_CUSTOM_INC}
)
target_include_directories(threadx_smp PRIVATE
    ${THREADX_SMP_GENERATED_INC_DIR}
)
target_compile_definitions(threadx_smp PRIVATE TX_QUEUE_MESSAGE_MAX_SIZE=16) #This is addressed in PR #503

add_custom_command(
    OUTPUT ${THREADX_SMP_OFFSET_INC}
    COMMAND ${CMAKE_COMMAND} -E make_directory ${THREADX_SMP_GENERATED_INC_DIR}
    COMMAND ${CMAKE_C_COMPILER}
    ${CMAKE_C_COMPILER_ARG1}
    ${THREADX_SMP_OFFSET_CFLAGS}
    ${THREADX_SMP_OFFSET_INCLUDE_ARGS}
    ${THREADX_SMP_OFFSET_DEFINE_ARGS}
    -S
    -o ${THREADX_SMP_OFFSET_ASM}
    ${THREADX_SMP_OFFSET_SOURCE}
    COMMAND ${CMAKE_COMMAND}
    -DINPUT=${THREADX_SMP_OFFSET_ASM}
    -DOUTPUT=${THREADX_SMP_OFFSET_INC}
    -P ${CMAKE_CURRENT_SOURCE_DIR}/cmake/GenerateAsmOffsets.cmake
    DEPENDS
    ${THREADX_SMP_OFFSET_SOURCE}
    ${CMAKE_CURRENT_SOURCE_DIR}/cmake/GenerateAsmOffsets.cmake
    ${CMAKE_CURRENT_SOURCE_DIR}/inc/tx_port.h
    ${THREADX_COMMON_SMP_DIR}/inc/tx_api.h
    COMMAND_EXPAND_LISTS
    VERBATIM
)

add_custom_target(threadx_smp_offsets DEPENDS ${THREADX_SMP_OFFSET_INC})
add_dependencies(threadx_smp threadx_smp_offsets)

add_executable(smp_demo)
target_include_directories(smp_demo PRIVATE
    ${CMAKE_CURRENT_SOURCE_DIR}/../moonlight
)
target_link_libraries(smp_demo PRIVATE threadx_smp)

target_sources(smp_demo PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/../../src/thread_demo/main.c)

#cmake -S . -B build -DCMAKE_TOOLCHAIN_FILE=$PWD/../../cmake/rv32gc_gnu.cmake -DCMAKE_EXPORT_COMPILE_COMMANDS=YES