set(MOONLIGHT_ROOT ${CMAKE_CURRENT_LIST_DIR})
set(THREADX4TGFS_ROOT ${CMAKE_CURRENT_SOURCE_DIR}/../..)
set(MOONLIGHT_SRC_DIR ${MOONLIGHT_ROOT}/src)
set(MOONLIGHT_INC_DIR ${MOONLIGHT_ROOT}/inc)

if(NOT DEFINED MOONLIGHT_TRAP_SOURCE)
  set(MOONLIGHT_TRAP_SOURCE ${MOONLIGHT_SRC_DIR}/trap_non_vectored.c)
endif()

set(MOONLIGHT_PLATFORM_SOURCES
  ${THREADX4TGFS_ROOT}/port/picolibc/port.c
  ${MOONLIGHT_SRC_DIR}/bootup.c
  ${MOONLIGHT_SRC_DIR}/board.c
  ${MOONLIGHT_TRAP_SOURCE}
  ${MOONLIGHT_SRC_DIR}/exception.c
  ${MOONLIGHT_SRC_DIR}/vector_table.c)

add_library(moonlight_platform_defaults INTERFACE)
target_include_directories(moonlight_platform_defaults INTERFACE
  ${MOONLIGHT_INC_DIR}
  ${THREADX4TGFS_ROOT}/src)
target_compile_options(moonlight_platform_defaults INTERFACE
  -ffreestanding
  -fno-builtin
  -fdata-sections
  -ffunction-sections)
target_link_directories(moonlight_platform_defaults INTERFACE
  ${THREADX4TGFS_ROOT}/src)
if(NX_DEBUG)
  target_compile_definitions(moonlight_platform_defaults INTERFACE
    NX_DEBUG
    NX_DEBUG_PACKET)
endif()

function(moonlight_define_platform TARGET THREADX_TARGET)
  add_library(${TARGET} OBJECT
    ${MOONLIGHT_PLATFORM_SOURCES})
  target_link_libraries(${TARGET} PUBLIC
    moonlight_platform_defaults
    c
    ${THREADX_TARGET})
endfunction()

moonlight_define_platform(moonlight_platform_common threadx)
if(TARGET threadx_smp)
  moonlight_define_platform(moonlight_platform_common_smp threadx_smp)
endif()

if(DEFINED NETXDUO_CUSTOM_PORT)
  add_library(moonlight_network_driver OBJECT
    ${MOONLIGHT_SRC_DIR}/mnrs_network_driver.c)
  target_link_libraries(moonlight_network_driver PUBLIC
    moonlight_platform_defaults
    c
    threadx
    netxduo)
endif()

function(target_add_moonlight_platform TARGET)
  set(options)
  set(oneValueArgs PLATFORM_TARGET)
  cmake_parse_arguments(TAMP "${options}" "${oneValueArgs}" "" ${ARGN})

  if(TAMP_UNPARSED_ARGUMENTS)
    message(FATAL_ERROR "target_add_moonlight_platform(${TARGET} ...): unknown args: ${TAMP_UNPARSED_ARGUMENTS}")
  endif()

  if(NOT TAMP_PLATFORM_TARGET)
    set(TAMP_PLATFORM_TARGET moonlight_platform_common)
  endif()

  target_link_libraries(${TARGET} PRIVATE ${TAMP_PLATFORM_TARGET})
endfunction()

function(target_add_moonlight_network_driver TARGET)
  if(NOT TARGET moonlight_network_driver)
    message(FATAL_ERROR "moonlight_network_driver requires netxduo to be available in this build")
  endif()

  target_link_libraries(${TARGET} PRIVATE moonlight_network_driver)
endfunction()