cmake_minimum_required(VERSION 3.21)
###############################################################################
# we are building embedded, so no shared libs
set(BUILD_SHARED_LIBS OFF)
include(${CMAKE_TOOLCHAIN_FILE})
###############################################################################
add_subdirectory(port/moonlight)
set(TARGET_MEM "ram" CACHE STRING "memory map to use")
###############################################################################
# Adds picolibc
#set(CMAKE_SYSTEM_PROCESSOR riscv)
set(__THREAD_LOCAL_STORAGE OFF)
add_subdirectory(third-party/picolibc)
#add_subdirectory(picolibc/semihost)
target_sources(c PRIVATE ${CMAKE_CURRENT_LIST_DIR}/port/picolibc/port.c)
target_link_libraries(c PUBLIC moonlight gcc)
###############################################################################
# Adds threadx
set(THREADX_CUSTOM_PORT ${CMAKE_CURRENT_LIST_DIR}/port/threadx)
add_subdirectory(third-party/threadx)
target_link_libraries(threadx PUBLIC c moonlight)
#Adds threadx_smp
add_subdirectory(port/threadx_smp)
target_link_libraries(threadx_smp PUBLIC c moonlight)
# Adds netxduo
set(NETXDUO_CUSTOM_PORT ${CMAKE_CURRENT_LIST_DIR}/port/netxduo)
set(NXD_ENABLE_FILE_SERVERS OFF)
add_subdirectory(third-party/netxduo)
if(NX_DEBUG)
  target_compile_definitions(netxduo PRIVATE NX_DEBUG NX_DEBUG_PACKET NX_ENABLE_PACKET_DEBUG_INFO)
endif()
if(TX_TRACE)
  target_compile_definitions(threadx PUBLIC TX_ENABLE_EVENT_TRACE)
  target_compile_definitions(threadx_smp PUBLIC TX_ENABLE_EVENT_TRACE)
  target_compile_definitions(netxduo PUBLIC TX_ENABLE_EVENT_TRACE)
endif()
###############################################################################
project(threadx_demo C ASM)
option(NX_DEBUG "compile netxduo debug output in" OFF)
option(TX_TRACE "Enable dump of traces to be read by TraceX" OFF)
set(CMAKE_EXECUTABLE_SUFFIX_C ".elf")

function(setup_target TARGET)
  set(options)
  set(multiValueArgs LIBRARIES SOURCES)
  cmake_parse_arguments(ST "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
  if(ST_UNPARSED_ARGUMENTS)
    message(FATAL_ERROR "setup_target(${TARGET} ...): unknown args: ${ST_UNPARSED_ARGUMENTS}")
  endif()

  add_executable(${TARGET})
  set_target_properties(${TARGET} PROPERTIES
    RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}
  )
  if(ST_SOURCES)
    target_sources(${TARGET} PRIVATE ${ST_SOURCES})
  endif()

  if(ST_LIBRARIES)
    target_link_libraries(${TARGET} PRIVATE ${ST_LIBRARIES})
  endif()

  target_link_options(${TARGET} PRIVATE
    -Wl,-Map=${CMAKE_BINARY_DIR}/${TARGET}.map)

  add_custom_command(TARGET ${TARGET} POST_BUILD
    COMMAND ${OBJCOPY} -O ihex $<TARGET_FILE:${TARGET}> ${CMAKE_BINARY_DIR}/${TARGET}.hex
    COMMAND ${OBJCOPY} -O binary $<TARGET_FILE:${TARGET}> ${CMAKE_BINARY_DIR}/${TARGET}.bin
    COMMAND ${SIZE} $<TARGET_FILE:${TARGET}>
    COMMAND ${OBJDUMP} -S $<TARGET_FILE:${TARGET}> > ${CMAKE_BINARY_DIR}/${TARGET}.dis
    COMMENT "Creating collateral for ${TARGET}"
  )
endfunction()

setup_target(thread_demo LIBRARIES threadx SOURCES src/thread_demo/main.c)
setup_target(tcp_demo LIBRARIES netxduo threadx SOURCES src/tcp_demo/main.c)
setup_target(smp_demo LIBRARIES threadx_smp SOURCES src/thread_demo/main.c)