cmake_minimum_required(VERSION 3.21)

set(BUILD_SHARED_LIBS OFF)
get_filename_component(THREADX4TGFS_ROOT "${CMAKE_CURRENT_LIST_DIR}/.." ABSOLUTE)

if(NOT DEFINED CMAKE_TOOLCHAIN_FILE)
  set(CMAKE_TOOLCHAIN_FILE
    ${THREADX4TGFS_ROOT}/cmake/rv32imac_gnu.cmake
    CACHE FILEPATH "Toolchain file")
endif()
include(${CMAKE_TOOLCHAIN_FILE})

set(__THREAD_LOCAL_STORAGE OFF)
add_subdirectory(${THREADX4TGFS_ROOT}/third-party/picolibc ${CMAKE_BINARY_DIR}/picolibc)
target_link_libraries(c PUBLIC gcc)

set(THREADX_CUSTOM_PORT ${THREADX4TGFS_ROOT}/port/threadx)
add_subdirectory(${THREADX4TGFS_ROOT}/third-party/threadx ${CMAKE_BINARY_DIR}/threadx)
target_link_libraries(threadx PUBLIC c)
target_compile_definitions(threadx PUBLIC TX_REGRESSION_TEST)

project(threadx_regression C ASM)
enable_testing()
set(TARGET_MEM "ram_dram" CACHE STRING "memory map to use")
set(CMAKE_EXECUTABLE_SUFFIX_C ".elf")

set(THREADX_TEST_SIMULATOR
  ""
  CACHE FILEPATH "Path to the RISC-V VP executable used by CTest")
if(NOT THREADX_TEST_SIMULATOR)
  message(FATAL_ERROR
    "THREADX_TEST_SIMULATOR is not set. Configure with -DTHREADX_TEST_SIMULATOR=/path/to/riscv-vp")
endif()

# Evaluate the variable from the toolchain file to decide which XLEN we are targetting (IMAC only!)
if(CMAKE_SYSTEM_PROCESSOR STREQUAL "risc-v32")
  set(THREADX_TEST_ISA "rv32imac_m")
elseif(CMAKE_SYSTEM_PROCESSOR STREQUAL "risc-v64")
  set(THREADX_TEST_ISA "rv64imac_m")
else()
  message(FATAL_ERROR
    "Unsupported CMAKE_SYSTEM_PROCESSOR for VP ISA selection: ${CMAKE_SYSTEM_PROCESSOR}")
endif()

# The regression tests require the Timer ISR to call the function test_interrupt_dispatch(void)
# We patch the current trap handler and include it using MOONLIGHT_TRAP_SOURCE.
set(MOONLIGHT_TRAP_SOURCE_INPUT ${THREADX4TGFS_ROOT}/port/moonlight/src/trap_non_vectored.c)
set(MOONLIGHT_TRAP_SOURCE ${CMAKE_BINARY_DIR}/generated/trap_non_vectored.c)
add_custom_command(
  OUTPUT ${MOONLIGHT_TRAP_SOURCE}
  COMMAND bash ${CMAKE_CURRENT_LIST_DIR}/threadx/generate_trap_file.sh
          ${MOONLIGHT_TRAP_SOURCE_INPUT}
          ${MOONLIGHT_TRAP_SOURCE}
  DEPENDS ${MOONLIGHT_TRAP_SOURCE_INPUT}
          ${CMAKE_CURRENT_LIST_DIR}/threadx/generate_trap_file.sh
  VERBATIM
)
add_custom_target(threadx_regression_generated_trap DEPENDS ${MOONLIGHT_TRAP_SOURCE})
set_source_files_properties(${MOONLIGHT_TRAP_SOURCE} PROPERTIES GENERATED TRUE)

add_subdirectory(${THREADX4TGFS_ROOT}/port/moonlight ${CMAKE_BINARY_DIR}/port/moonlight)
add_dependencies(moonlight_platform_common threadx_regression_generated_trap)

function(setup_target TARGET)
  set(options)
  set(multiValueArgs LIBRARIES SOURCES)
  cmake_parse_arguments(ST "${options}" "" "${multiValueArgs}" ${ARGN})
  if(ST_UNPARSED_ARGUMENTS)
    message(FATAL_ERROR "setup_target(${TARGET} ...): unknown args: ${ST_UNPARSED_ARGUMENTS}")
  endif()

  add_executable(${TARGET})
  set_target_properties(${TARGET} PROPERTIES
    RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}
  )
  target_add_moonlight_platform(${TARGET})

  if(ST_SOURCES)
    target_sources(${TARGET} PRIVATE ${ST_SOURCES})
  endif()

  if(ST_LIBRARIES)
    target_link_libraries(${TARGET} PRIVATE ${ST_LIBRARIES})
  endif()

  target_link_options(${TARGET} PRIVATE
    -nostartfiles
    -nostdlib
    -T ${THREADX4TGFS_ROOT}/src/${TARGET_MEM}.lds
    -Wl,--gc-sections
    -Wl,-Map=${CMAKE_BINARY_DIR}/${TARGET}.map)

  add_custom_command(TARGET ${TARGET} POST_BUILD
    COMMAND ${OBJCOPY} -O ihex $<TARGET_FILE:${TARGET}> ${CMAKE_BINARY_DIR}/${TARGET}.hex
    COMMAND ${OBJCOPY} -O binary $<TARGET_FILE:${TARGET}> ${CMAKE_BINARY_DIR}/${TARGET}.bin
    #COMMAND ${SIZE} $<TARGET_FILE:${TARGET}>
    COMMAND ${OBJDUMP} -S $<TARGET_FILE:${TARGET}> > ${CMAKE_BINARY_DIR}/${TARGET}.dis
    #COMMENT "Creating collateral for ${TARGET}"
  )
endfunction()

add_subdirectory(threadx regression_targets)