cmake_minimum_required(VERSION 3.24)
project(smp_demo LANGUAGES C ASM)

include(${CMAKE_CURRENT_SOURCE_DIR}/cmake/ThreadXSmpOffsets.cmake)

set(THREADX_COMMON_SMP_DIR ${CMAKE_CURRENT_SOURCE_DIR}/../../third-party/threadx/common_smp)
if(NOT EXISTS "${THREADX_COMMON_SMP_DIR}")
    message(FATAL_ERROR "could not find ThreadX SMP sources, is the submodule checked out?")
endif()

set(THREADX_SMP_CUSTOM_INC
    ${CMAKE_CURRENT_SOURCE_DIR}/inc
    ${CMAKE_CURRENT_SOURCE_DIR}/../moonlight #needed for aclint (inter process interrupts)
)
set(THREADX_SMP_CUSTOM_SRC
    src/tx_initialize_low_level.S
    src/tx_thread_context_restore.S
    src/tx_thread_context_save.S
    src/tx_thread_schedule.S
    src/tx_thread_smp_core_get.S
    src/tx_thread_smp_core_preempt.c
    src/tx_thread_smp_current_state_get.S
    src/tx_thread_smp_current_thread_get.S
    src/tx_thread_smp_initialize_wait.S
    src/tx_thread_smp_low_level_initialize.S
    src/tx_thread_smp_protect.S
    src/tx_thread_smp_unprotect.S
    src/tx_thread_stack_build.S
    src/tx_thread_system_return.S
)

threadx_smp_add_offsets(
    TARGET threadx_smp_offsets
    OUTPUT_DIR ${CMAKE_CURRENT_BINARY_DIR}/generated
    SOURCE ${CMAKE_CURRENT_SOURCE_DIR}/src/tx_asm_offsets.c
    INCLUDE_DIRS
    ${THREADX_COMMON_SMP_DIR}/inc
    ${THREADX_SMP_CUSTOM_INC}
    DEPENDS
    ${CMAKE_CURRENT_SOURCE_DIR}/inc/tx_port.h
    ${THREADX_COMMON_SMP_DIR}/inc/tx_api.h
    OUT_INCLUDE_DIR THREADX_SMP_GENERATED_INC_DIR
)

file(GLOB THREADX_SMP_SOURCES ${THREADX_COMMON_SMP_DIR}/src/*.c)
add_library(threadx_smp STATIC)
target_sources(threadx_smp PRIVATE
    ${THREADX_SMP_SOURCES}
    ${THREADX_SMP_CUSTOM_SRC}
)
target_include_directories(threadx_smp PUBLIC
    ${THREADX_COMMON_SMP_DIR}/inc
    ${THREADX_SMP_CUSTOM_INC}
)
target_include_directories(threadx_smp PRIVATE
    ${THREADX_SMP_GENERATED_INC_DIR}
)
target_compile_definitions(threadx_smp PRIVATE TX_QUEUE_MESSAGE_MAX_SIZE=16) #This is addressed in PR #503
add_dependencies(threadx_smp threadx_smp_offsets)